Buenos días a todos,

Necesito ayuda para crear una macro que cree tantas hojas nuevas como referencias diferentes tenga una columna.

Se ha de filtrar una columna ©, y dependiendo de los datos de dicha columna (10 diferentes), creará tantas hojas como referencias tenga.

No se si me he explicado claramente, adjunto el archivo que he creado.

Gracias a todos, estamos en contacto.

Datos.rar

No comprendo bien el enunciado.

He visto el archivo y veo que la columna C tiene las referencias y las filtras y aparecen todas las filas que contienen la misma referencia.

Lo que quieres hacer es poner una Hoja nueva en el mismo archivo que contienes la plantilla por cada fila que tiene esa misma referencia?

Es eso?

Hola michico,

Lo que quiero hacer es un libro nuevo con cada una de las referencias y todos sus datos.

No se si esto es posible o no.

Te mando unos archivos de ejemplo.

Gracias,

Desktop.rar

Buenos días,

He conseguido hacer algo que lo que preguntaba, pero no del todo.

He podido filtrar la columna en nuevas hojas, no en nuevos libros,

Si alguien puede ayudarme de como hacerlo en nuevos libros, se lo agradecería.

Un saludo.

Os mando el archivo.

excel.rar

Buenos días,

He consegido hacer algo que lo que pedía, pero no del todo.

He podido filtrar la columna en nuevas hojas, no en nuevos libros, que era lo que necesitaba.

Si alguien puede ayudarme de como hacerlo en nuevos libros, se lo agradecería.

Un saludo.

Os mando el archivo.

excel.rar

Hola,

Mmm... Dejame que me aclare quieres que en vez de tener pestañas con las referencias comunes, libros nuevos?

Sin embargo para este tipo de cosas yo utilizaría un programa orientado a base de datos. Porque estos datos los sacarías con una simple búsqueda.

PedroBCN,

Trabajaremos sobre tu código, aunque a mi parecer tiene demasiada paja pero lo dejaremos así ya que por el momento no cuento con demasiado tiempo para pulirlo.

Únicamente cambie 2 lineas de tu código actual, sustituye el código por éste otro que te anexo que realiza la tarea que requieres.

Sub CopyToWorksh()
    'Note: This macro use the function LastRow
    Dim My_Range As Range
    Dim FieldNum As Long
    Dim CalcMode As Long
    Dim ViewMode As Long
    Dim ws2 As Worksheet
    Dim Lrow As Long
    Dim cell As Range
    Dim CCount As Long
    Dim WSNew As Worksheet
    Dim ErrNum As Long

    'Set filter range on ActiveSheet: A1 is the top left cell of your filter range
    'and the header of the first column, D is the last column in the filter range.
    'You can also add the sheet name to the code like this :
    'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1")))
    'No need that the sheet is active then when you run the macro when you use this.
    Set My_Range = ThisWorkbook.Worksheets(1).UsedRange
    My_Range.Parent.Select

    If ActiveWorkbook.ProtectStructure = True Or _
       My_Range.Parent.ProtectContents = True Then
        MsgBox "Sorry, not working when the workbook or worksheet is protected", _
               vbOKOnly, "Copy to new worksheet"
        Exit Sub
    End If

    'This example filters on the first column in the range(change the field if needed)
    'In this case the range starts in A so Field:=1 is column A, 2 = column B, ......
    FieldNum = 1

    'Turn off AutoFilter
    My_Range.Parent.AutoFilterMode = False

    'Change ScreenUpdating, Calculation, EnableEvents, ....
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With
    ViewMode = ActiveWindow.View
    ActiveWindow.View = xlNormalView
    ActiveSheet.DisplayPageBreaks = False

    'Add a worksheet to copy the a unique list and add the CriteriaRange
    Set ws2 = Worksheets.Add

    With ws2
        'first we copy the Unique data from the filter field to ws2
        My_Range.Columns(FieldNum).AdvancedFilter _
                Action:=xlFilterCopy, _
                CopyToRange:=.Range("A1"), Unique:=True

        'loop through the unique list in ws2 and filter/copy to a new sheet
        Lrow = .Cells(Rows.Count, "A").End(xlUp).Row
        For Each cell In .Range("A2:A" & Lrow)

            'Filter the range
            My_Range.AutoFilter Field:=FieldNum, Criteria1:="=" & _
             Replace(Replace(Replace(cell.Value, "~", "~~"), "*", "~*"), "?", "~?")

            'Check if there are no more then 8192 areas(limit of areas)
            CCount = 0
            On Error Resume Next
            CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible) _
                     .Areas(1).Cells.Count
            On Error GoTo 0
            If CCount = 0 Then
                MsgBox "There are more than 8192 areas for the value : " & cell.Value _
                     & vbNewLine & "It is not possible to copy the visible data." _
                     & vbNewLine & "Tip: Sort your data before you use this macro.", _
                       vbOKOnly, "Split in worksheets"
            Else


                'Add a new worksheet


                '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                '>>> Estas Fueron las líneas que cambie >>>
                '>>> Editado por Obed Cruz >>>>>>>>>>>>>>>>

                Set WkbNew = Workbooks.Add
                Set WSNew = WkbNew.Worksheets(1)

                '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>



                On Error Resume Next
                WSNew.Name = cell.Value
                If Err.Number > 0 Then
                    ErrNum = ErrNum + 1
                    WSNew.Name = "Error_" & Format(ErrNum, "0000")
                    Err.Clear
                End If
                On Error GoTo 0

                'Copy the visible data to the new worksheet
                My_Range.SpecialCells(xlCellTypeVisible).Copy
                With WSNew.Range("c1")
                    ' Paste:=8 will copy the columnwidth in Excel 2000 and higher
                    ' Remove this line if you use Excel 97
                    .PasteSpecial Paste:=8
                    .PasteSpecial xlPasteValues
                    .PasteSpecial xlPasteFormats
                    Application.CutCopyMode = False
                    .Select
                End With
            End If

            'Show all data in the range
            My_Range.AutoFilter Field:=FieldNum

        Next cell

        'Delete the ws2 sheet
        On Error Resume Next
        Application.DisplayAlerts = False
        .Delete
        Application.DisplayAlerts = True
        On Error GoTo 0

    End With

    'Turn off AutoFilter
    My_Range.Parent.AutoFilterMode = False

    If ErrNum > 0 Then
        MsgBox "Rename every WorkSheet name that start with ""Error_"" manually" _
             & vbNewLine & "There are characters in the name that are not allowed" _
             & vbNewLine & "in a sheet name or the worksheet already exist."
    End If

    'Restore ScreenUpdating, Calculation, EnableEvents, ....

    ActiveWindow.View = ViewMode
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With

End Sub[/HTML]

Hola,

Así es. Que me recomiendas que haga entonces?.

Lo que ocurres, es que antes de esta macro, el excel tiene varias más, que hacen otras cosas, hasta llegar a esta.

Muchas gracias Obed_cruz,

Ya estaba con una paja mental que era demasiado.

Va de fábula lo que mandaste.

Un saludo.

Hola,

Así es. Que me recomiendas que haga entonces?.

Lo que ocurres, es que antes de esta macro, el excel tiene varias más, que hacen otras cosas, hasta llegar a esta.

La solución Obed_Cruz es la buena. Pero cuando vas a necesitar tanto dato es mejor pensar en una base de datos, pues ya incorpora sistemas de búsqueda. Me imagino que el Acces es un buen ejemplo. Sin embargo yo no lo he utilizado. Lo poco que se, me baso en MySQL donde por comando escribes lo que buscas y te hace un listado. Excel es buena herramienta pero creo que tener una hoja para cada caso es redundante (es decir, tendremos mucha información repetida) y en una BD no se debería permitir.

Luegotambién es bueno en pensar en los archivos *.csv porque no copian formato y separan todo con un simbolo separador. Es un consejo, ahorras capacidad y excel tm los lee.

Pero bueno, es como todo yo personalmente uso el excel para casi todo. De calculadora, de BD, de calendario, de todo... y no debería de ser así.

Un saludo,