Como llamar datos filtrados

[Yuuki]

Tengo un programa donde quiero hay objetos que tienen: ID, Clave, Nombre, Tipo, etc. Entonces el tipo consta de que tipo de producto es, puede tener varios. Ya hice una manera para separarlos y ponerlos en un combobox. lo que quiero hacer es que el tipo que escoja se muestren todos los que son de ese tipo. Lo que hago ahorita es filtralo y quiero escojer los que estan filtrados nada mas, pero al momento de mover el offset se va atraves de los que estan escondidos tambien. Ya intente ponerle un if hidden pero no funciono. Aqui esta el programa. Es la hoja de catalogo interno y en la macro es el revint. Cualquier pregunta aqui estoy.

BDRicardo.zip

[Guest Cacho R]

Hola! Yuuki. Asocia al evento Change del ComboBox1 lo siguiente:

Private Sub ComboBox1_Change()
Dim C As Range, ii As Byte, LR As Long
Application.ScreenUpdating = False

With Sheet3: .Activate: .AutoFilterMode = False: End With
LR = [a65536].End(xlUp).Row
[a1].CurrentRegion.AutoFilter Field:=4, Criteria1:="=*" & ComboBox1 & "*", Operator:=xlAnd

Rem Uso de la función Subtotales para determinar si el filtro entregó información
If WorksheetFunction.Subtotal(103, [a:a]) = 1 Then
  MsgBox "Sin información para: 'Tipo = " & ComboBox1 & "'"
  Exit Sub
End If

Rem Limpiamos los ListBox
For ii = 4 To 9
  Me.Controls("ListBox" & ii).Clear
Next ii

Rem Uso de SpecialCells(xlCellTypeVisible) para detectar las celdas visibles
For Each C In Range("a3:a" & LR).SpecialCells(xlCellTypeVisible)

  Rem ListBox3.AddItem ID (No encontré el ListBox3 por ningún lado...)

  ListBox4.AddItem C.Offset(0, 1)
  ListBox5.AddItem C.Offset(0, 2)
  ListBox6.AddItem C.Offset(0, 4)
  ListBox7.AddItem C.Offset(0, 5)
  ListBox8.AddItem C.Offset(0, 7)
  ListBox9.AddItem C.Offset(0, 8)
Next C

ActiveSheet.AutoFilterMode = False
Application.ScreenUpdating = True
End Sub[/PHP]

[size=3][font=comic sans ms]Tienes algunos otros detalles para optimizar la depuración del código, pero no hacen al tema de tu consulta.

Saludos, Cacho R.[/font][/size]