UNIFICAR FORMULA FUNCION SI ANIDADA

[SALAVERRINO 11]

Buenas tardes a los integrantes del foro, en esta ocasión recurro a uds, para que brinde su apoyo en como unificar la formula siguiente

1º formula: REDONDEAR(SI(Y(A3<>"WEJ1";A3<>"WEJ2";A3<>"WEJ3");0;SI(B3>1000;C3*15%;0));2),

2º formula: REDONDEAR(SI(Y(A3<>"MEJ1";A3<>"MEJ2";A3<>"MEJ3");0;SI(B3>1000;C3*8%;0));2)

ya que actualmente la trabajo 2 celdas y luego sumo ambos resultados, como se aprecia en el siguiente archivo que adjunto, desde ya agradezco su apoyo y colaboración.

Saludos.

 

UNIFICAR FORMULA.xlsx

[Snake 300]

Hola:

únelas con el signo de +  fórmula1+formula2

 

[John Jairo V 2,590]

¡Hola, a ambos!

Puedes también probar con:

=(B3>1000)*(REDONDEAR(O(A3="WEJ"&{1;2;3})*C3*15%;2)+REDONDEAR(O(A3="MEJ"&{1;2;3})*C3*8%;2))

Nota: Mi separador de argumentos es ";".  Si no es el tuyo, cámbialo por "," o por el que maneje tu sistema.  ¡Bendiciones!

[GabrielRaigosa 1,125]

Otra opción:

=REDONDEAR(C3*(B3>1000)*((IZQUIERDA(A3)="W")*15%+(IZQUIERDA(A3)="M")*8%),2)

 

[John Jairo V 2,590]

¡Hola, a ambos!

Podríamos usar, también:

=(B3>1000)*SUMA(REDONDEAR(C3*(IZQUIERDA(A3)={"W";"M"})*{15;8}%;2))

Aunque, para ser precisos con lo que muestra el consultante, se puede usar:

=(B3>1000)*SUMA(REDONDEAR(C3*(A3={"WEJ"\"MEJ"}&{1;2;3})*{15\8}%;2))

Creo que hay que puntualizar que, aunque en el ejemplo del consultante no hay diferencia, no es lo mismo redondear una suma entre dos valores, que sumar dos valores redondeados.

¡Bendiciones!

[SALAVERRINO 11]

Buenas noches  a los integrantes @Snake @johnmpl @GabrielRaigosa por sus excelente aportes los cuales me ayudaron mucho en como unificar 2 fórmulas en 1 y a través de ese criterio las adapte a otras fórmulas, por lo que les agradezco su apoyo y colaboración, por lo que daría como TEMA SOLUCIONADO. 

Bendiciones.