Colocar encabezado en listbox

[woodixd]

Estimados Buenos dias.

Alguien por favor que me ayude con el encabezado de mi listbox

lo he intentado con esto :

ListBox1.ColumnHeads = True

listado.RowSource = "hoja1!A2:R3"[/CODE]

pero me sale error cuando agrego esta linea, creo que estoy generando un conflicto de funciones.

les adjunto el archivo para mejor visualizacion

los datos que extrae el listbox en la busqueda estan en la hoja (hoja1)

Dropbox - Proyeccion - Hor.xlsm

[Antoni]

.

Te has equivocado en el nombre del ListBox

listado.ColumnHeads = True

listado.RowSource = "hoja1!A2:R3"

[/CODE]

.

[woodixd]

macro antonio buenos dias.

gracias por tu ayuda. y tu interes se tambien que eres uno de los grandes aqui en el foro.

pero el ejemplo de codigo fue referencial , puesto que en mi programacion orginal lo tengo asi :

 With Listado

    'Asignamos 22 columnas de la tabla

    .ColumnCount = 22

    'Definimos el tamaño de las columnas

    .ColumnWidths = "40 pt; 180 pt;80 pt; 100 pt;300 pt; 80 pt;80 pt; 80 pt; 80 pt;80 pt;80 pt;80 pt;80 pt;20 pt;100 pt;20 pt;120 pt;20 pt;"

'    .RowSource = "Hoja1!A2:R3"

    .ColumnHeads = True


End With[/CODE]

ahora como podras ver si habres el archivo te daras cuenta que al darle click en una celda de la columna B con titulo EAM. me llama un formulario en el cual muestra en el listbox1 (listado). el detalle de el codigo en el cual le diste click.

fue por eso motivo que comente que lo que quizas estaba haciendo un conflicto con el codigo.

puesto que le pido llenar con el rowsource. pero a la vez estoy llenando el listbox con la busqueda. lo unico que me hace falta es ese emcabezado,

aun me falta mucho para aprender macros a tu nivel, puesto que estube revisando un codigo tuyo. con un label, pero no lo he entendido por mas que lo he estudiado ya varias veces :'(.

[Antoni]

.

Efectivamente, no puedes combinar RowSource y Additem, y solo puede aparecer el encabezamiento si utilizas RowSource.

Si esperas a mañana te preparo un forma de "saltarnos" esta limitación.

.

[woodixd]

Claro macro antonio. Esperare tu respuesta.

Adicionalmente seguire investigando. Muchas gracias por tu interes. Quedo a espera de tu solucion.

Saludos

[Antoni]

Te dejo el código del formulario:

Dim T As Worksheet, H As Worksheet


Private Sub CommandButton1_Click()

Unload Me

End Sub

'----------------------------------------

Private Sub EliminarHojaDeTrabajo()

On Error Resume Next

Application.DisplayAlerts = False

Sheets("Trabajo").Delete

Application.DisplayAlerts = True

End Sub

'--------------------------------

Private Sub UserForm_Initialize()

Application.ScreenUpdating = False


EliminarHojaDeTrabajo

Sheets.Add

ActiveSheet.Name = "Trabajo"


Set T = Sheets("Trabajo")

Set H = Sheets("Hoja1")


H.Rows(1).Copy T.Rows(1)

With Listado

    'Asignamos 22 columnas de la tabla

    .ColumnCount = 22

    'Definimos el tamaño de las columnas

    .ColumnWidths = "75 pt; 80 pt;180 pt; 100 pt;300 pt; 80 pt;80 pt;" & _

                    "80 pt; 80 pt;80 pt;80 pt;80 pt;80 pt;60 pt;100 pt;60 pt;120 pt;100 pt;"

    .ColumnHeads = True

End With

Label1.Caption = sUnidad

Label3.Caption = sfecha

Label4.Caption = ObtenerNombreUsuario

Call Cargar_ots

End Sub

'--------------------------------------

Sub Cargar_ots()

Dim Fila As Long

Application.ScreenUpdating = False

Fila = 2

For x = 2 To H.Range("A" & Rows.Count).End(xlUp).Row

  If H.Range("A" & x) = sUnidad Then

      H.Rows(x).Copy T.Rows(Fila)

      T.Cells(Fila, Listado.ColumnCount + 1) = x 'Fila de la Hoja1

      Fila = Fila + 1

  End If

Next

Listado.RowSource = T.Name & "!A2:R" & Fila

H.Select

End Sub

'----------------------------------------

Private Sub UserForm_Terminate()

EliminarHojaDeTrabajo

End Sub

[/CODE]

.

[b][size=5][color=#0000ff]En lugar de intentar llenar la consulta en el listbox fila a fila, llenamos una hoja de trabajo que creamos al cargar el formulario y eliminamos al descargarlo. De esta manera podemos utilizar la propiedad [u]RowSource[/u].[/color]

.[/size][/b]

[woodixd]

Estimado macro antonmio disculparas mi ignorancia pero donde coloco ese codigo.

y para el caso tendria que crear una hoja nueva llamada "trabajo" o dicha hoja es la que hace referencia a mi "hoja1" en la cual esta el listado de OT.

lamento la molestia, las disculpas del caso.

[woodixd]

listo ya lo encontre. era en los eventos del formulario la hoja trabajo era una hoja temporal si no me equivoco, gracias por tu ayuda. sguire estudiando tu codigo a ver si aprendo un poco mas.

Cada dia tengo el gusto de encontrarme con grandes maestros de excel en este foro y aprender un poco mas. Nueva,mente gracias por tu interes y ayuda.

TEMA SOLUCIONADO.